import at_record_web/model.{LoggedOut, ShelfLoading}
import at_record_web/msg.{GotAvatar, GotLogout, Logout}
import at_record_web/pages/login
import at_record_web/update.{update}
import gleam/option.{None, Some}
import gleam/string
import lustre/element
import support.{base, logged_in}

pub fn login_submits_through_a_form_test() {
  let html = login.view(base()) |> element.to_string
  assert string.contains(html, "<form")
  assert string.contains(html, "type=\"submit\"")
  assert string.contains(html, "LOG IN WITH ATPROTO")
}

pub fn oauth_error_copy_maps_known_codes_test() {
  assert string.contains(
    login.error_copy("access_denied"),
    "turned the request",
  )
  assert login.error_copy("state_mismatch") == login.error_copy("bad_callback")
  assert string.contains(
    login.error_copy("token_exchange_failed"),
    "token exchange",
  )
  assert string.contains(
    login.error_copy("session_failed"),
    "save your session",
  )
  assert string.contains(login.error_copy("resolve_failed"), "handle's PDS")
  assert login.error_copy("something_new") == "Login failed. Try again."
}

pub fn logout_clears_session_test() {
  let #(model, _) = update(logged_in(), Logout)
  assert model.auth == LoggedOut
  assert model.shelf == ShelfLoading
}

pub fn got_logout_logs_out_test() {
  let #(model, _) = update(logged_in(), GotLogout)
  assert model.auth == LoggedOut
}

pub fn got_avatar_stores_it_and_logout_clears_it_test() {
  let #(with_avatar, _) =
    update(logged_in(), GotAvatar(Ok(Some("https://example.test/a.jpg"))))
  assert with_avatar.avatar == Some("https://example.test/a.jpg")
  let #(after_logout, _) = update(with_avatar, Logout)
  assert after_logout.avatar == None
}