diff --git a/core.xsl b/core.xsl
new file mode 100644
index 0000000..8f7e32a
--- /dev/null
+++ b/core.xsl
@@ -0,0 +1,116 @@
+<?xml version="1.0"?>
+<!-- SPDX-License-Identifier: CC0-1.0 -->
+<xsl:stylesheet version="1.0"
+  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+  xmlns:f="http://www.jonmsterling.com/jms-005P.xml"
+  xmlns:mml="http://www.w3.org/1998/Math/MathML"
+  xmlns:xhtml="http://www.w3.org/1999/xhtml">
+
+  <!-- The following ensures that node not matched by a template will show up as an error. -->
+  <xsl:template match="node()|@*">
+    <xsl:copy>
+      <span style="background-color:red">
+        <xsl:text>[</xsl:text>
+        <xsl:value-of select="name(.)" />
+        <xsl:text>]</xsl:text>
+      </span>
+      <span style="background-color:red">
+        <xsl:apply-templates select="node()|@*" />
+      </span>
+    </xsl:copy>
+  </xsl:template>
+
+  <!-- HTML and MathML nodes should be copied with namespace prefixes stripped.-->
+  <xsl:template match="mml:*|xhtml:*">
+    <xsl:element name="{local-name()}">
+      <xsl:apply-templates select="@* | node()" />
+    </xsl:element>
+  </xsl:template>
+
+  <xsl:template match="@mml:* | @xhtml:*">
+    <xsl:attribute name="{local-name()}">
+      <xsl:value-of select="." />
+    </xsl:attribute>
+  </xsl:template>
+  
+  
+  <xsl:template match="f:p">
+    <p>
+      <xsl:apply-templates />
+    </p>
+  </xsl:template>
+
+  <xsl:template match="f:code">
+    <code>
+      <xsl:apply-templates />
+    </code>
+  </xsl:template>
+
+  <xsl:template match="f:pre">
+    <pre>
+      <xsl:apply-templates />
+    </pre>
+  </xsl:template>
+
+  <xsl:template match="f:em">
+    <em>
+      <xsl:apply-templates />
+    </em>
+  </xsl:template>
+
+  <xsl:template match="f:strong">
+    <strong>
+      <xsl:apply-templates />
+    </strong>
+  </xsl:template>
+
+  <xsl:template match="f:ol">
+    <ol>
+      <xsl:apply-templates />
+    </ol>
+  </xsl:template>
+
+  <xsl:template match="f:ul">
+    <ul>
+      <xsl:apply-templates />
+    </ul>
+  </xsl:template>
+
+  <xsl:template match="f:li">
+    <li>
+      <xsl:apply-templates />
+    </li>
+  </xsl:template>
+
+  <xsl:template match="f:blockquote">
+    <blockquote>
+      <xsl:apply-templates />
+    </blockquote>
+  </xsl:template>
+  
+  
+  <xsl:template match="f:embedded-tex">
+    <center>
+      <img src="resources/{@hash}.svg" />
+    </center>
+  </xsl:template>
+
+  <xsl:template match="f:error">
+    <span class="error">
+      <xsl:apply-templates />
+    </span>
+  </xsl:template>
+
+  <xsl:template match="f:tex[@f:display='block']">
+    <xsl:text>\[</xsl:text>
+    <xsl:value-of select="." />
+    <xsl:text>\]</xsl:text>
+  </xsl:template>
+
+  <xsl:template match="f:tex[not(@f:display='block')]">
+    <xsl:text>\(</xsl:text>
+    <xsl:value-of select="." />
+    <xsl:text>\)</xsl:text>
+  </xsl:template>
+
+</xsl:stylesheet>
diff --git a/forest.xsl b/forest.xsl
index 0c8660c..f74e9ae 100644
--- a/forest.xsl
+++ b/forest.xsl
@@ -1,376 +1,14 @@
 <?xml version="1.0"?>
 <!-- SPDX-License-Identifier: CC0-1.0 -->
-<xsl:stylesheet version="1.0"
-  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
-  xmlns:mml="http://www.w3.org/1998/Math/MathML"
-  xmlns:f="http://www.jonmsterling.com/jms-005P.xml">
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
- <xsl:output method="html" encoding="utf-8" indent="yes" doctype-public="" doctype-system="" />
+  <xsl:output method="html" encoding="utf-8" indent="yes" doctype-public="" doctype-system="" />
 
- <xsl:include href="metadata.xsl" />
- <xsl:include href="links.xsl" />
+  <xsl:include href="core.xsl" />
+  <xsl:include href="metadata.xsl" />
+  <xsl:include href="links.xsl" />
+  <xsl:include href="tree.xsl" />
 
- <xsl:key
-  name="tree-with-addr"
-  match="/f:tree/f:mainmatter//f:tree"
-  use="f:frontmatter/f:addr/text()" />
-
- <!-- The following ensures that node not matched by a template will simply be
-   copied into the output. -->
- <xsl:template match="node()|@*">
-  <xsl:copy>
-   <span style="background-color:red">
-    <xsl:text>[</xsl:text>
-    <xsl:value-of select="name(.)" />
-    <xsl:text>]</xsl:text>
-   </span>
-   <span style="background-color:red">
-    <xsl:apply-templates select="node()|@*" />
-   </span>
-  </xsl:copy>
- </xsl:template>
-
- <xsl:template match="mml:*">
-  <xsl:copy>
-   <xsl:apply-templates select="node()|@*" />
-  </xsl:copy>
- </xsl:template>
-
- <xsl:template
-  match="f:p | f:img | f:code | f:pre | f:em | f:strong | f:ol | f:ul | f:li | f:blockquote | table | tr | th | td | ruby | rb | rt | rp | span | figure | figcaption | mark | div | hr | abbr | sub | sup">
-  <xsl:copy>
-   <xsl:apply-templates select="node()|@*" />
-  </xsl:copy>
- </xsl:template>
-
- <!-- <xsl:template match="pause"></xsl:template> -->
-
- <xsl:template match="f:embedded-tex">
-  <center>
-   <img src="resources/{@hash}.svg" />
-  </center>
- </xsl:template>
-
- <xsl:template match="f:error">
-  <span class="error">
-   <xsl:apply-templates />
-  </span>
- </xsl:template>
-
- <xsl:template match="f:tex[@f:display='block']">
-  <xsl:text>\[</xsl:text>
-  <xsl:value-of select="." />
-  <xsl:text>\]</xsl:text>
- </xsl:template>
-
- <xsl:template match="f:tex[not(@f:display='block')]">
-  <xsl:text>\(</xsl:text>
-  <xsl:value-of select="." />
-  <xsl:text>\)</xsl:text>
- </xsl:template>
-
- <xsl:template match="/">
-  <html>
-   <head>
-    <meta name="viewport" content="width=device-width" />
-    <link rel="stylesheet" href="style.css" />
-    <link rel="stylesheet" href="katex.min.css" />
-    <script type="text/javascript">
-     <xsl:if test="/f:tree/f:frontmatter/f:source-path">
-      <xsl:text>window.sourcePath = '</xsl:text>
-      <xsl:value-of select="/f:tree/f:frontmatter/f:source-path" />
-      <xsl:text>'</xsl:text>
-     </xsl:if>
-    </script>
-    <script type="module" src="forester.js"></script>
-    <title>
-     <xsl:value-of select="/f:tree/f:frontmatter/f:title" />
-    </title>
-   </head>
-   <body>
-    <ninja-keys placeholder="Start typing a note title or ID"></ninja-keys>
-    <xsl:if test="not(/f:tree[@f:root = 'true'])">
-     <header class="header">
-      <nav class="nav">
-       <div class="logo">
-        <a href="index.xml" title="Home">
-         <xsl:text>« Home</xsl:text>
-        </a>
-       </div>
-      </nav>
-     </header>
-    </xsl:if>
-    <div id="grid-wrapper">
-     <article>
-      <xsl:apply-templates select="f:tree" />
-     </article>
-     <xsl:if
-      test="f:tree/f:mainmatter/f:tree[not(@f:toc='false')] and not(/f:tree/f:frontmatter/f:meta[@f:name = 'toc']/.='false')">
-      <nav id="toc">
-       <div class="block">
-        <h1>Table of Contents</h1>
-        <xsl:apply-templates select="f:tree/f:mainmatter" mode="toc" />
-       </div>
-      </nav>
-     </xsl:if>
-    </div>
-   </body>
-  </html>
- </xsl:template>
-
- <xsl:template name="numbered-taxon">
-  <span class="taxon">
-   <xsl:apply-templates select="f:taxon" />
-   <xsl:if test="(not(../@f:numbered='false') and not(../@f:toc='false') and count(../../f:tree) > 1) or f:number">
-    <xsl:if test="f:taxon">
-     <xsl:text>&#160;</xsl:text>
-    </xsl:if>
-    <xsl:choose>
-     <xsl:when test="f:number">
-      <xsl:value-of select="f:number" />
-     </xsl:when>
-     <xsl:otherwise>
-      <xsl:number format="1.1" count="f:tree[ancestor::f:tree and not(@f:toc='false') and not(@f:numbered='false')]" level="multiple" />
-     </xsl:otherwise>
-    </xsl:choose>
-   </xsl:if>
-   <xsl:if
-    test="f:taxon or (not(../@f:numbered='false') and not(../@f:toc='false') and count(../../f:tree) > 1) or f:number">
-    <xsl:text>.&#160;</xsl:text>
-   </xsl:if>
-  </span>
- </xsl:template>
-
- <xsl:template match="f:tree" mode="toc">
-  <li>
-   <xsl:for-each select="f:frontmatter">
-    <a href="{f:route}" class="bullet" title="{f:title} [{f:addr}]">■</a>
-    <span class="link local" data-target="#tree-{f:anchor}">
-     <xsl:call-template name="numbered-taxon" />
-     <xsl:apply-templates select="f:title" />
-    </span>
-   </xsl:for-each>
-   <xsl:apply-templates select="f:mainmatter" mode="toc" />
-  </li>
- </xsl:template>
-
- <xsl:template match="f:mainmatter" mode="toc">
-  <ul class="block">
-   <xsl:apply-templates select="f:tree[not(@f:toc='false')]" mode="toc" />
-  </ul>
- </xsl:template>
-
- <xsl:template match="f:frontmatter/f:title">
-  <xsl:apply-templates />
- </xsl:template>
-
- <xsl:template match="f:mainmatter">
-  <div class="f:tree-content">
-   <xsl:apply-templates />
-  </div>
- </xsl:template>
-
- <xsl:template match="f:addr">
-  <a class="slug" href="{../f:route}">
-   <xsl:text>[</xsl:text>
-   <xsl:value-of select="." />
-   <xsl:text>]</xsl:text>
-  </a>
- </xsl:template>
-
- <xsl:template match="f:source-path">
-  <a class="edit-button" href="{concat('vscode://file', .)}">
-   <xsl:text>[edit]</xsl:text>
-  </a>
- </xsl:template>
-
- <xsl:template match="f:taxon">
-  <xsl:value-of select="." />
- </xsl:template>
-
- <xsl:template match="f:frontmatter">
-  <header>
-   <h1>
-    <xsl:call-template name="numbered-taxon" />
-    <xsl:apply-templates select="f:title" />
-    <xsl:text>&#032;</xsl:text>
-    <xsl:apply-templates select="f:addr" />
-    <xsl:text>&#032;</xsl:text>
-    <xsl:apply-templates select="f:source-path" />
-   </h1>
-   <div class="metadata">
-    <ul>
-     <xsl:apply-templates select="f:date" />
-     <xsl:if test="not(f:meta[@f:name = 'author']/.='false')">
-      <xsl:apply-templates select="f:authors" />
-     </xsl:if>
-     <xsl:apply-templates select="f:meta[@f:name='position']" />
-     <xsl:apply-templates select="f:meta[@f:name='institution']" />
-     <xsl:apply-templates select="f:meta[@f:name='venue']" />
-     <xsl:apply-templates select="f:meta[@f:name='source']" />
-     <xsl:apply-templates select="f:meta[@f:name='doi']" />
-     <xsl:apply-templates select="f:meta[@f:name='orcid']" />
-     <xsl:apply-templates select="f:meta[@f:name='external']" />
-     <xsl:apply-templates select="f:meta[@f:name='slides']" />
-     <xsl:apply-templates select="f:meta[@f:name='video']" />
-    </ul>
-   </div>
-  </header>
- </xsl:template>
-
- <xsl:template match="f:tree" mode="tree-number">
-  <xsl:choose>
-   <xsl:when test="f:frontmatter/f:number">
-    <xsl:value-of select="f:frontmatter/f:number" />
-   </xsl:when>
-   <xsl:otherwise>
-    <xsl:number format="1.1" count="f:tree[ancestor::f:tree and not(@f:toc='false') and not(@f:numbered='false')]" level="multiple" />
-   </xsl:otherwise>
-  </xsl:choose>
- </xsl:template>
-
- <xsl:template match="f:ref">
-  <a class="link local">
-   <xsl:attribute name="href">
-    <xsl:choose>
-     <xsl:when test="key('tree-with-addr',current()/@f:addr)">
-      <xsl:text>#tree-</xsl:text>
-      <xsl:value-of select="key('tree-with-addr',current()/@f:addr)/f:frontmatter/f:anchor" />
-     </xsl:when>
-     <xsl:otherwise>
-      <xsl:value-of select="@f:href" />
-     </xsl:otherwise>
-    </xsl:choose>
-   </xsl:attribute>
-
-   <xsl:choose>
-    <xsl:when test="@f:taxon">
-     <xsl:value-of select="@f:taxon" />
-    </xsl:when>
-    <xsl:otherwise>§</xsl:otherwise>
-   </xsl:choose>
-   <xsl:text>&#160;</xsl:text>
-   <xsl:choose>
-    <xsl:when test="@f:number">
-     <xsl:value-of select="@f:number" />
-    </xsl:when>
-    <xsl:when test="key('tree-with-addr',current()/@f:addr)[not(@f:numbered='false') and not(@f:toc='false')]">
-     <xsl:apply-templates select="key('tree-with-addr',current()/@f:addr)[1]" mode="tree-number" />
-    </xsl:when>
-    <xsl:otherwise>
-     <xsl:text>[</xsl:text>
-     <xsl:value-of select="@f:addr" />
-     <xsl:text>]</xsl:text>
-    </xsl:otherwise>
-   </xsl:choose>
-  </a>
- </xsl:template>
-
- <xsl:template match="f:backmatter/f:references" mode="title">
-  <xsl:text>References</xsl:text>
- </xsl:template>
-
- <xsl:template match="f:backmatter/f:context" mode="title">
-  <xsl:text>Context</xsl:text>
- </xsl:template>
-
- <xsl:template match="f:backmatter/f:contributions" mode="title">
-  <xsl:text>Contributions</xsl:text>
- </xsl:template>
-
- <xsl:template match="f:backmatter/f:related" mode="title">
-  <xsl:text>Related</xsl:text>
- </xsl:template>
-
- <xsl:template match="f:backmatter/f:backlinks" mode="title">
-  <xsl:text>Backlinks</xsl:text>
- </xsl:template>
-
- <xsl:template match="f:backmatter/f:references|f:backmatter/f:context|f:backmatter/f:contributions|f:backmatter/f:related|f:backmatter/f:backlinks">
-  <xsl:if test="f:tree">
-   <section class="block link-list">
-    <h2>
-     <xsl:apply-templates select="." mode="title" />
-    </h2>
-    <xsl:apply-templates select="f:tree" />
-   </section>
-  </xsl:if>
- </xsl:template>
-
- <xsl:template match="/f:tree[not(@root='true')]/f:backmatter">
-  <footer>
-   <xsl:apply-templates select="f:references" />
-   <xsl:apply-templates select="f:context" />
-   <xsl:apply-templates select="f:backlinks" />
-   <xsl:apply-templates select="f:related" />
-   <xsl:apply-templates select="f:contributions" />
-  </footer>
- </xsl:template>
-
- <xsl:template match="/f:tree[@root='true']/f:backmatter">
- </xsl:template>
-
- <xsl:template match="f:tree">
-  <section>
-   <xsl:attribute name="lang">
-    <xsl:choose>
-     <xsl:when test="f:frontmatter/f:meta[@f:name='lang']">
-      <xsl:value-of select="f:frontmatter/f:meta[@f:name='lang']" />
-     </xsl:when>
-     <xsl:otherwise>en</xsl:otherwise>
-    </xsl:choose>
-   </xsl:attribute>
-
-   <xsl:choose>
-    <xsl:when test="@f:show-metadata = 'false'">
-     <xsl:attribute name="class">block hide-metadata</xsl:attribute>
-    </xsl:when>
-    <xsl:otherwise>
-     <xsl:attribute name="class">block</xsl:attribute>
-    </xsl:otherwise>
-   </xsl:choose>
-   <xsl:if test="f:frontmatter/taxon">
-    <xsl:attribute name="data-taxon">
-     <xsl:value-of select="f:frontmatter/taxon" />
-    </xsl:attribute>
-   </xsl:if>
-
-   <xsl:choose>
-    <xsl:when test="not(@f:show-heading='false')">
-     <details id="{concat('tree-',f:frontmatter/f:anchor)}">
-      <xsl:if test="not(@f:expanded = 'false')">
-       <xsl:attribute name="open">open</xsl:attribute>
-      </xsl:if>
-      <summary>
-       <xsl:apply-templates select="f:frontmatter" />
-      </summary>
-      <xsl:apply-templates select="f:mainmatter" />
-      <xsl:apply-templates select="f:frontmatter/f:meta[@f:name='bibtex']" />
-     </details>
-    </xsl:when>
-    <xsl:otherwise>
-     <xsl:apply-templates select="f:mainmatter" />
-    </xsl:otherwise>
-   </xsl:choose>
-  </section>
-
-  <xsl:apply-templates select="f:backmatter" />
- </xsl:template>
-
- <xsl:template match="f:backmatter/*/f:tree">
-  <section class="block">
-   <xsl:if test="f:frontmatter/f:taxon">
-    <xsl:attribute name="data-taxon">
-     <xsl:value-of select="f:frontmatter/f:taxon" />
-    </xsl:attribute>
-   </xsl:if>
-   <details>
-    <summary>
-     <xsl:apply-templates select="f:frontmatter" />
-    </summary>
-    <xsl:apply-templates select="f:mainmatter" />
-   </details>
-  </section>
- </xsl:template>
+  <!-- <xsl:template match="pause"></xsl:template> -->
 
 </xsl:stylesheet>
diff --git a/tree.xsl b/tree.xsl
new file mode 100644
index 0000000..3118a2f
--- /dev/null
+++ b/tree.xsl
@@ -0,0 +1,311 @@
+<?xml version="1.0"?>
+<!-- SPDX-License-Identifier: CC0-1.0 -->
+<xsl:stylesheet version="1.0"
+  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+  xmlns:f="http://www.jonmsterling.com/jms-005P.xml">
+
+  <xsl:key name="tree-with-addr" match="/f:tree/f:mainmatter//f:tree" use="f:frontmatter/f:addr/text()" />
+
+  <xsl:template match="/">
+    <html>
+      <head>
+        <meta name="viewport" content="width=device-width" />
+        <link rel="stylesheet" href="style.css" />
+        <link rel="stylesheet" href="katex.min.css" />
+        <script type="text/javascript">
+          <xsl:if test="/f:tree/f:frontmatter/f:source-path">
+            <xsl:text>window.sourcePath = '</xsl:text>
+            <xsl:value-of select="/f:tree/f:frontmatter/f:source-path" />
+            <xsl:text>'</xsl:text>
+          </xsl:if>
+        </script>
+        <script type="module" src="forester.js"></script>
+        <title>
+          <xsl:value-of select="/f:tree/f:frontmatter/f:title" />
+        </title>
+      </head>
+      <body>
+        <ninja-keys placeholder="Start typing a note title or ID"></ninja-keys>
+        <xsl:if test="not(/f:tree[@f:root = 'true'])">
+          <header class="header">
+            <nav class="nav">
+              <div class="logo">
+                <a href="index.xml" title="Home">
+                  <xsl:text>« Home</xsl:text>
+                </a>
+              </div>
+            </nav>
+          </header>
+        </xsl:if>
+        <div id="grid-wrapper">
+          <article>
+            <xsl:apply-templates select="f:tree" />
+          </article>
+          <xsl:if test="f:tree/f:mainmatter/f:tree[not(@f:toc='false')] and not(/f:tree/f:frontmatter/f:meta[@f:name = 'toc']/.='false')">
+            <nav id="toc">
+              <div class="block">
+                <h1>Table of Contents</h1>
+                <xsl:apply-templates select="f:tree/f:mainmatter" mode="toc" />
+              </div>
+            </nav>
+          </xsl:if>
+        </div>
+      </body>
+    </html>
+  </xsl:template>
+
+  <xsl:template name="numbered-taxon">
+    <span class="taxon">
+      <xsl:apply-templates select="f:taxon" />
+      <xsl:if test="(not(../@f:numbered='false') and not(../@f:toc='false') and count(../../f:tree) > 1) or f:number">
+        <xsl:if test="f:taxon">
+          <xsl:text>&#160;</xsl:text>
+        </xsl:if>
+        <xsl:choose>
+          <xsl:when test="f:number">
+            <xsl:value-of select="f:number" />
+          </xsl:when>
+          <xsl:otherwise>
+            <xsl:number format="1.1" count="f:tree[ancestor::f:tree and not(@f:toc='false') and not(@f:numbered='false')]" level="multiple" />
+          </xsl:otherwise>
+        </xsl:choose>
+      </xsl:if>
+      <xsl:if test="f:taxon or (not(../@f:numbered='false') and not(../@f:toc='false') and count(../../f:tree) > 1) or f:number">
+        <xsl:text>.&#160;</xsl:text>
+      </xsl:if>
+    </span>
+  </xsl:template>
+
+  <xsl:template match="f:tree" mode="toc">
+    <li>
+      <xsl:for-each select="f:frontmatter">
+        <a href="{f:route}" class="bullet" title="{f:title} [{f:addr}]">■</a>
+        <span class="link local" data-target="#tree-{f:anchor}">
+          <xsl:call-template name="numbered-taxon" />
+          <xsl:apply-templates select="f:title" />
+        </span>
+      </xsl:for-each>
+      <xsl:apply-templates select="f:mainmatter" mode="toc" />
+    </li>
+  </xsl:template>
+
+  <xsl:template match="f:mainmatter" mode="toc">
+    <ul class="block">
+      <xsl:apply-templates select="f:tree[not(@f:toc='false')]" mode="toc" />
+    </ul>
+  </xsl:template>
+
+  <xsl:template match="f:frontmatter/f:title">
+    <xsl:apply-templates />
+  </xsl:template>
+
+  <xsl:template match="f:mainmatter">
+    <div class="f:tree-content">
+      <xsl:apply-templates />
+    </div>
+  </xsl:template>
+
+  <xsl:template match="f:addr">
+    <a class="slug" href="{../f:route}">
+      <xsl:text>[</xsl:text>
+      <xsl:value-of select="." />
+      <xsl:text>]</xsl:text>
+    </a>
+  </xsl:template>
+
+  <xsl:template match="f:source-path">
+    <a class="edit-button" href="{concat('vscode://file', .)}">
+      <xsl:text>[edit]</xsl:text>
+    </a>
+  </xsl:template>
+
+  <xsl:template match="f:taxon">
+    <xsl:value-of select="." />
+  </xsl:template>
+
+  <xsl:template match="f:frontmatter">
+    <header>
+      <h1>
+        <xsl:call-template name="numbered-taxon" />
+        <xsl:apply-templates select="f:title" />
+        <xsl:text>&#032;</xsl:text>
+        <xsl:apply-templates select="f:addr" />
+        <xsl:text>&#032;</xsl:text>
+        <xsl:apply-templates select="f:source-path" />
+      </h1>
+      <div class="metadata">
+        <ul>
+          <xsl:apply-templates select="f:date" />
+          <xsl:if test="not(f:meta[@f:name = 'author']/.='false')">
+            <xsl:apply-templates select="f:authors" />
+          </xsl:if>
+          <xsl:apply-templates select="f:meta[@f:name='position']" />
+          <xsl:apply-templates select="f:meta[@f:name='institution']" />
+          <xsl:apply-templates select="f:meta[@f:name='venue']" />
+          <xsl:apply-templates select="f:meta[@f:name='source']" />
+          <xsl:apply-templates select="f:meta[@f:name='doi']" />
+          <xsl:apply-templates select="f:meta[@f:name='orcid']" />
+          <xsl:apply-templates select="f:meta[@f:name='external']" />
+          <xsl:apply-templates select="f:meta[@f:name='slides']" />
+          <xsl:apply-templates select="f:meta[@f:name='video']" />
+        </ul>
+      </div>
+    </header>
+  </xsl:template>
+
+  <xsl:template match="f:tree" mode="tree-number">
+    <xsl:choose>
+      <xsl:when test="f:frontmatter/f:number">
+        <xsl:value-of select="f:frontmatter/f:number" />
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:number format="1.1" count="f:tree[ancestor::f:tree and not(@f:toc='false') and not(@f:numbered='false')]" level="multiple" />
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+
+  <xsl:template match="f:ref">
+    <a class="link local">
+      <xsl:attribute name="href">
+        <xsl:choose>
+          <xsl:when test="key('tree-with-addr',current()/@f:addr)">
+            <xsl:text>#tree-</xsl:text>
+            <xsl:value-of select="key('tree-with-addr',current()/@f:addr)/f:frontmatter/f:anchor" />
+          </xsl:when>
+          <xsl:otherwise>
+            <xsl:value-of select="@f:href" />
+          </xsl:otherwise>
+        </xsl:choose>
+      </xsl:attribute>
+
+      <xsl:choose>
+        <xsl:when test="@f:taxon">
+          <xsl:value-of select="@f:taxon" />
+        </xsl:when>
+        <xsl:otherwise>§</xsl:otherwise>
+      </xsl:choose>
+      <xsl:text>&#160;</xsl:text>
+      <xsl:choose>
+        <xsl:when test="@f:number">
+          <xsl:value-of select="@f:number" />
+        </xsl:when>
+        <xsl:when test="key('tree-with-addr',current()/@f:addr)[not(@f:numbered='false') and not(@f:toc='false')]">
+          <xsl:apply-templates select="key('tree-with-addr',current()/@f:addr)[1]" mode="tree-number" />
+        </xsl:when>
+        <xsl:otherwise>
+          <xsl:text>[</xsl:text>
+          <xsl:value-of select="@f:addr" />
+          <xsl:text>]</xsl:text>
+        </xsl:otherwise>
+      </xsl:choose>
+    </a>
+  </xsl:template>
+
+  <xsl:template match="f:backmatter/f:references" mode="title">
+    <xsl:text>References</xsl:text>
+  </xsl:template>
+
+  <xsl:template match="f:backmatter/f:context" mode="title">
+    <xsl:text>Context</xsl:text>
+  </xsl:template>
+
+  <xsl:template match="f:backmatter/f:contributions" mode="title">
+    <xsl:text>Contributions</xsl:text>
+  </xsl:template>
+
+  <xsl:template match="f:backmatter/f:related" mode="title">
+    <xsl:text>Related</xsl:text>
+  </xsl:template>
+
+  <xsl:template match="f:backmatter/f:backlinks" mode="title">
+    <xsl:text>Backlinks</xsl:text>
+  </xsl:template>
+
+  <xsl:template match="f:backmatter/f:references|f:backmatter/f:context|f:backmatter/f:contributions|f:backmatter/f:related|f:backmatter/f:backlinks">
+    <xsl:if test="f:tree">
+      <section class="block link-list">
+        <h2>
+          <xsl:apply-templates select="." mode="title" />
+        </h2>
+        <xsl:apply-templates select="f:tree" />
+      </section>
+    </xsl:if>
+  </xsl:template>
+
+  <xsl:template match="/f:tree[not(@root='true')]/f:backmatter">
+    <footer>
+      <xsl:apply-templates select="f:references" />
+      <xsl:apply-templates select="f:context" />
+      <xsl:apply-templates select="f:backlinks" />
+      <xsl:apply-templates select="f:related" />
+      <xsl:apply-templates select="f:contributions" />
+    </footer>
+  </xsl:template>
+
+  <xsl:template match="/f:tree[@root='true']/f:backmatter">
+  </xsl:template>
+
+  <xsl:template match="f:tree">
+    <section>
+      <xsl:attribute name="lang">
+        <xsl:choose>
+          <xsl:when test="f:frontmatter/f:meta[@f:name='lang']">
+            <xsl:value-of select="f:frontmatter/f:meta[@f:name='lang']" />
+          </xsl:when>
+          <xsl:otherwise>en</xsl:otherwise>
+        </xsl:choose>
+      </xsl:attribute>
+
+      <xsl:choose>
+        <xsl:when test="@f:show-metadata = 'false'">
+          <xsl:attribute name="class">block hide-metadata</xsl:attribute>
+        </xsl:when>
+        <xsl:otherwise>
+          <xsl:attribute name="class">block</xsl:attribute>
+        </xsl:otherwise>
+      </xsl:choose>
+      <xsl:if test="f:frontmatter/taxon">
+        <xsl:attribute name="data-taxon">
+          <xsl:value-of select="f:frontmatter/taxon" />
+        </xsl:attribute>
+      </xsl:if>
+
+      <xsl:choose>
+        <xsl:when test="not(@f:show-heading='false')">
+          <details id="{concat('tree-',f:frontmatter/f:anchor)}">
+            <xsl:if test="not(@f:expanded = 'false')">
+              <xsl:attribute name="open">open</xsl:attribute>
+            </xsl:if>
+            <summary>
+              <xsl:apply-templates select="f:frontmatter" />
+            </summary>
+            <xsl:apply-templates select="f:mainmatter" />
+            <xsl:apply-templates select="f:frontmatter/f:meta[@f:name='bibtex']" />
+          </details>
+        </xsl:when>
+        <xsl:otherwise>
+          <xsl:apply-templates select="f:mainmatter" />
+        </xsl:otherwise>
+      </xsl:choose>
+    </section>
+
+    <xsl:apply-templates select="f:backmatter" />
+  </xsl:template>
+
+  <xsl:template match="f:backmatter/*/f:tree">
+    <section class="block">
+      <xsl:if test="f:frontmatter/f:taxon">
+        <xsl:attribute name="data-taxon">
+          <xsl:value-of select="f:frontmatter/f:taxon" />
+        </xsl:attribute>
+      </xsl:if>
+      <details>
+        <summary>
+          <xsl:apply-templates select="f:frontmatter" />
+        </summary>
+        <xsl:apply-templates select="f:mainmatter" />
+      </details>
+    </section>
+  </xsl:template>
+
+</xsl:stylesheet>