{ config, pkgs, lib, unstable, ... }:

{
  imports = [ ../hermes.nix ];

  environment.etc."ctrld/config.toml" = {
    mode = "0644";
    text = ''
      [server]
      listen = "0.0.0.0:53"
      tcp_enable = true

      [upstream.dns]
      primary = "76.76.2.22#etf79xdaho.dns.controld.com"
    '';
  };

  hardware.nvidia-container-toolkit.enable = true;
  virtualisation.docker.daemon.settings = {
    features.cdi = true;
    insecure-registries = [ "localhost:5005" ];
  };

  # Pin kernel to 6.12 LTS — NVIDIA 595 driver doesn't build against 7.2 yet
  # (implicit strncpy declaration error; missing <string.h> in nvidia sources).
  # Revisit when nixpkgs bumps nvidiaPackages past 595.
  boot.kernelPackages = lib.mkForce pkgs.linuxPackages_6_12;

  hardware.nvidia = {
    modesetting.enable = true;
    open = false;
    nvidiaSettings = true;
    package = config.boot.kernelPackages.nvidiaPackages.stable;
  };

  hardware.graphics.extraPackages = with pkgs; [
    nvidia-vaapi-driver
    config.boot.kernelPackages.nvidiaPackages.stable
  ];

  services.xserver.videoDrivers = [ "nvidia" ];

  environment.sessionVariables = {
    GBM_BACKEND = "nvidia-drm";
    __GLX_VENDOR_LIBRARY_NAME = "nvidia";
    LIBVA_DRIVER_NAME = "nvidia";
    NIXOS_OZONE_WL = "1";
    MOZ_ENABLE_WAYLAND = "1";
  };

  environment.systemPackages = with pkgs; [
    # Pinned to stable nixpkgs (20.3.2). Unstable's 21.0.4 SIGSEGVs at
    # QDialog::setVisible under NVIDIA + XWayland — env-var wrappers
    # (__NV_DISABLE_EXPLICIT_SYNC, QT_XCB_GL_INTEGRATION) didn't fix it.
    # Revisit when nixpkgs-unstable ships a later 21.x that stops crashing.
    (davinci-resolve-studio.override {
      buildFHSEnv = args: buildFHSEnv (args // {
        targetPkgs = ps: (args.targetPkgs ps) ++ [ ps.pulseaudio ];
      });
    })
    cdrtools
    dconf-editor
    lollypop
  ];

  users.users.jgarr.extraGroups = [ "cdrom" ];

}