From 1184f4e5ea709e1b4d395d532f63df85bc7a883f Mon Sep 17 00:00:00 2001
From: Michael Davis <mcarsondavis@gmail.com>
Date: Sun, 31 May 2026 12:01:05 -0400
Subject: [PATCH] queries: Inline CSS queries into less highlights

Less has a lot of overlap with the css queries but it doesn't have node
names which we are matching on with recent changes to the css queries.
So this change adds the old css highlights to the less highlights.
---
 runtime/queries/less/highlights.scm | 96 +++++++++++++++++++++++++----
 1 file changed, 83 insertions(+), 13 deletions(-)

diff --git a/runtime/queries/less/highlights.scm b/runtime/queries/less/highlights.scm
index 2a3ebce5..05fedd5b 100644
--- a/runtime/queries/less/highlights.scm
+++ b/runtime/queries/less/highlights.scm
@@ -1,35 +1,105 @@
-; inherits: css
-
-[
-  "@import"
-  "@namespace"
-  "@charset"
-] @keyword
-
+(comment) @comment
 (js_comment) @comment
 
-(function_name) @function
+[
+  (tag_name)
+  (nesting_selector)
+  (universal_selector)
+] @tag
 
 [
+  "~"
+  ">"
+  "+"
+  "-"
+  "*"
+  "/"
+  "="
+  "^="
+  "|="
+  "~="
+  "$="
+  "*="
   ">="
   "<="
 ] @operator
 
+[
+  "and"
+  "not"
+  "only"
+  "or"
+] @keyword.operator
+
+(attribute_selector (plain_value) @string)
+
+(property_name) @variable.other.member
 (plain_value) @string
 
-(keyword_query) @function
+((property_name) @variable
+  (#match? @variable "^--"))
+((plain_value) @variable
+  (#match? @variable "^--"))
 
-(identifier) @variable
+(class_name) @label
+(feature_name) @variable.other.member
+(function_name) @function
+(id_name) @label
+(namespace_name) @namespace
 
+(identifier) @variable
 (variable) @variable
 
-(arguments
-  (variable) @variable.parameter)
+(attribute_name) @attribute
+(pseudo_element_selector (tag_name) @attribute)
+(pseudo_class_selector (class_name) @attribute)
+
+[
+  "@charset"
+  "@import"
+  "@keyframes"
+  "@media"
+  "@namespace"
+  "@supports"
+  (at_keyword)
+  (from)
+  (important)
+  (to)
+  (keyword_query)
+  (keyframes_name)
+  (unit)
+] @keyword
+
+[
+  "#"
+  "."
+] @punctuation
+
+(string_value) @string
+(color_value "#" @string.special)
+(color_value) @string.special
+
+(integer_value) @constant.numeric.integer
+(float_value) @constant.numeric.float
 
 [
+  ")"
+  "("
   "["
   "]"
+  "{"
+  "}"
 ] @punctuation.bracket
 
+[
+  ","
+  ";"
+  ":"
+  "::"
+] @punctuation.delimiter
+
+(arguments
+  (variable) @variable.parameter)
+
 (import_statement
   (identifier) @function)
-- 
2.51.2