{
  description = "future_form";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    command-utils.url = "git+https://codeberg.org/expede/nix-command-utils";
  };

  outputs = {
    self,
    flake-utils,
    nixpkgs,
    rust-overlay,
    command-utils,
  } @ inputs:
    flake-utils.lib.eachDefaultSystem (
      system: let
        overlays = [
          (import rust-overlay)
        ];

        pkgs = import nixpkgs {
          inherit system overlays;
          config.allowUnfree = true;
        };

        rustVersion = "1.90.0";

        rust-toolchain = (pkgs.rust-bin.stable.${rustVersion}.default.override {
          extensions = [
            "cargo"
            "clippy"
            "llvm-tools-preview"
            "rust-src"
            "rust-std"
            "rustfmt"
          ];

          targets = [
            "aarch64-apple-darwin"
            "x86_64-apple-darwin"

            "x86_64-unknown-linux-musl"
            "aarch64-unknown-linux-musl"

            "wasm32-unknown-unknown"
            "thumbv6m-none-eabi"
          ];
        }).overrideAttrs (old: {
          meta = (old.meta or {}) // { mainProgram = "cargo"; };
        });

        format-pkgs = with pkgs; [
          nixpkgs-fmt
          alejandra
          taplo
        ];

        cargo-installs = with pkgs; [
          cargo-component
          cargo-deny
          cargo-expand
          cargo-hack
          cargo-outdated
          cargo-semver-checks
          cargo-sort
          cargo-udeps
          typos
        ];

        # Command utils
        rust = command-utils.rust.${system};
        asModule = command-utils.asModule.${system};
        cmd = command-utils.cmd.${system};
        cargo = "${rust-toolchain}/bin/cargo";

        menu = command-utils.commands.${system} [
          (rust.test { cargo = rust-toolchain; cargo-watch = pkgs.cargo-watch; })
          (rust.lint { cargo = rust-toolchain; })
          (rust.fmt { cargo = rust-toolchain; })
          (rust.build { cargo = rust-toolchain; })
          (rust.doc { cargo = rust-toolchain; })
          (rust.watch { cargo-watch = pkgs.cargo-watch; })
          (rust.audit { cargo-audit = pkgs.cargo-audit; })
          (rust.semver { cargo-semver-checks = pkgs.cargo-semver-checks; })
          (rust.ci { cargo = rust-toolchain; })
          (asModule {
            "ffi:test" = cmd "Run FFI e2e tests (Go, Java, Python)"
              "${cargo} test --workspace --test ffi_e2e -- --include-ignored --nocapture";
            "ffi:test:example" = cmd "Run example crate unit tests"
              "${cargo} test --manifest-path future_form_ffi/examples/counter_effects/counter_effects/Cargo.toml && ${cargo} test --manifest-path future_form_ffi/examples/key_value_store/kv_store/Cargo.toml";
          })
        ];

        ci-rust-toolchain = (pkgs.rust-bin.stable.${rustVersion}.default.override {
          extensions = [
            "cargo"
            "clippy"
            "rustfmt"
          ];

          targets = [
            "wasm32-unknown-unknown"
          ];
        }).overrideAttrs (old: {
          meta = (old.meta or {}) // { mainProgram = "cargo"; };
        });

        # Stub so tools that probe for rustup (e.g. cargo-semver-checks)
        # silently succeed instead of failing with "No such file or directory".
        rustup-shim = pkgs.writeShellScriptBin "rustup" ''
          if [ "$1" = "--version" ]; then
            echo "rustup-nix-shim"
          elif [ "$1" = "toolchain" ]; then
            exit 0
          elif [ "$1" = "which" ]; then
            command -v "$2" 2>/dev/null || echo "$2"
          else
            exit 0
          fi
        '';

        ci-cargo-installs = with pkgs; [
          cargo-deny
          cargo-hack
          cargo-semver-checks
          typos
        ];

      in rec {
        devShells.default = pkgs.mkShell {
          name = "future_form shell";

          nativeBuildInputs = with pkgs;
            [
              rust-toolchain
              rust-analyzer
            ]
            ++ menu
            ++ format-pkgs
            ++ cargo-installs;

          shellHook = ''
            unset SOURCE_DATE_EPOCH
            export WORKSPACE_ROOT="$(pwd)"
            menu
          '';
        };

        devShells.ci = pkgs.mkShell {
          name = "future_form ci";

          nativeBuildInputs =
            [
              ci-rust-toolchain
              rustup-shim
            ]
            ++ ci-cargo-installs;
        };

        devShells.ffi = pkgs.mkShell {
          name = "future_form ffi shell";
          inputsFrom = [devShells.ci];
          nativeBuildInputs = [pkgs.go pkgs.jdk pkgs.python3];
        };

        formatter = pkgs.alejandra;
      }
    );
}