diff --git a/after/queries/html/injections.scm b/after/queries/html/injections.scm
new file mode 100644
index 0000000..aa132af
--- /dev/null
+++ b/after/queries/html/injections.scm
@@ -0,0 +1,46 @@
+; inherits html
+
+; <div hx-on:click="foo()">
+(attribute
+  (attribute_name) @_name
+  (#lua-match? @_name "^hx%-on:")
+  (quoted_attribute_value
+    (attribute_value) @injection.content)
+  (#set! injection.language "javascript"))
+
+; <div hx-vals='js:{...}'>
+(attribute
+  (attribute_name) @_name
+  (#lua-match? @_name "^hx%-vals")
+  (quoted_attribute_value
+    (attribute_value) @injection.content)
+  (#lua-match? @injection.content "^js:")
+  (#offset! @injection.content 0 2 0 0)
+  (#set! injection.language "javascript"))
+
+; <div hx-vals='javascript:{...}'>
+(attribute
+  (attribute_name) @_name
+  (#lua-match? @_name "^hx%-vals")
+  (quoted_attribute_value
+    (attribute_value) @injection.content)
+  (#lua-match? @injection.content "^javascript:")
+  (#offset! @injection.content 0 11 0 0)
+  (#set! injection.language "javascript"))
+
+; <meta name="htmx-config" content='{...}'>
+(start_tag
+  (tag_name) @_meta
+  (#eq? @_meta "meta")
+  (attribute
+    (attribute_name) @_attr
+    (#eq? @_attr "name")
+    (quoted_attribute_value
+      (attribute_value) @_name
+      (#eq? @_name "htmx-config")))
+  (attribute
+    (attribute_name) @_content
+    (#eq? @_content "content")
+    (quoted_attribute_value
+      (attribute_value) @injection.content))
+  (#set! injection.language "json"))
diff --git a/after/queries/toml/injections.scm b/after/queries/toml/injections.scm
new file mode 100644
index 0000000..a7ef503
--- /dev/null
+++ b/after/queries/toml/injections.scm
@@ -0,0 +1,8 @@
+; inherits toml
+
+; """#!/usr/bin/env bash
+(
+  (string ["\"\"\"" "'''"]) @_str @injection.content
+  (#lua-match? @_str "^...#!.*bash")
+  (#offset! @injection.content 0 3 0 3)
+  (#set! injection.language "bash"))