diff --git a/README.md b/README.md
new file mode 100644
index 0000000..738b2bd
--- /dev/null
+++ b/README.md
@@ -0,0 +1,25 @@
+# My dotfiles
+
+## Installation
+
+```bash
+git clone 'https://github.com/boltlessengineer/dotfiles.git'
+
+cd dotfiles
+
+# install neovim config
+ln -s ./nvim ~/.config/nvim
+
+# install fish config
+ln -s ./fish ~/.config/fish
+
+# install lf config
+ln -s ./lf ~/.config/lf
+```
+
+### install fish
+```bash
+brew install fish
+fish
+fisher update
+```
diff --git a/bat/config b/bat/config
new file mode 100644
index 0000000..418eeb7
--- /dev/null
+++ b/bat/config
@@ -0,0 +1,25 @@
+# This is `bat`s configuration file. Each line either contains a comment or
+# a command-line option that you want to pass to `bat` by default. You can
+# run `bat --help` to get a list of all possible configuration options.
+
+# Specify desired highlighting theme (e.g. "TwoDark"). Run `bat --list-themes`
+# for a list of all available themes
+--theme="TwoDark"
+
+# Enable this to use italic text on the terminal. This is not supported on all
+# terminal emulators (like tmux, by default):
+#--italic-text=always
+
+# Uncomment the following line to disable automatic paging:
+#--paging=never
+
+# Uncomment the following line if you are using less version >= 551 and want to
+# enable mouse scrolling support in `bat` when running inside tmux. This might
+# disable text selection, unless you press shift.
+#--pager="less --RAW-CONTROL-CHARS --quit-if-one-screen --mouse"
+
+# Syntax mappings: map a certain filename pattern to a language.
+#   Example 1: use the C++ syntax for Arduino .ino files
+#   Example 2: Use ".gitignore"-style highlighting for ".ignore" files
+--map-syntax "*.ino:C++"
+#--map-syntax ".ignore:Git Ignore"
diff --git a/fish/completions/fisher.fish b/fish/completions/fisher.fish
new file mode 100644
index 0000000..6d23ce4
--- /dev/null
+++ b/fish/completions/fisher.fish
@@ -0,0 +1,7 @@
+complete --command fisher --exclusive --long help --description "Print help"
+complete --command fisher --exclusive --long version --description "Print version"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments install --description "Install plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments update --description "Update installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments remove --description "Remove installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments list --description "List installed plugins matching regex"
+complete --command fisher --exclusive --condition "__fish_seen_subcommand_from update remove" --arguments "(fisher list)"
diff --git a/fish/completions/nvm.fish b/fish/completions/nvm.fish
new file mode 100644
index 0000000..e94e50c
--- /dev/null
+++ b/fish/completions/nvm.fish
@@ -0,0 +1,19 @@
+complete --command nvm --exclusive --long version --description "Print version"
+complete --command nvm --exclusive --long help --description "Print help"
+
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments install --description "Download and activate the specified Node version"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments use --description "Activate a version in the current shell"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list --description "List installed versions"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list-remote --description "List versions available to install matching optional regex"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments current --description "Print the currently-active version"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from install" --arguments "(
+    test -e $nvm_data && string split ' ' <$nvm_data/.index
+)"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use" --arguments "(_nvm_list | string split ' ')"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments uninstall --description "Uninstall a version"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from uninstall" --arguments "(
+    _nvm_list | string split ' ' | string replace system ''
+)"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use uninstall" --arguments "(
+    set --query nvm_default_version && echo default
+)"
diff --git a/fish/conf.d/nvm.fish b/fish/conf.d/nvm.fish
new file mode 100644
index 0000000..347c2bd
--- /dev/null
+++ b/fish/conf.d/nvm.fish
@@ -0,0 +1,28 @@
+function _nvm_install --on-event nvm_install
+    set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
+    set --universal nvm_data $XDG_DATA_HOME/nvm
+    set --query nvm_mirror || set --universal nvm_mirror https://nodejs.org/dist
+
+    test ! -d $nvm_data && command mkdir -p $nvm_data
+    echo "Downloading the Node distribution index..." 2>/dev/null
+    _nvm_index_update $nvm_mirror $nvm_data/.index
+end
+
+function _nvm_update --on-event nvm_update
+    set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
+    set --universal nvm_data $XDG_DATA_HOME/nvm
+    set --query nvm_mirror || set --universal nvm_mirror https://nodejs.org/dist
+end
+
+function _nvm_uninstall --on-event nvm_uninstall
+    command rm -rf $nvm_data
+
+    set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
+
+    set --names | string replace --filter --regex -- "^nvm" "set --erase nvm" | source
+    functions --erase (functions --all | string match --entire --regex -- "^_nvm_")
+end
+
+if status is-interactive && set --query nvm_default_version && ! set --query nvm_current_version
+    nvm use $nvm_default_version >/dev/null
+end
diff --git a/fish/config.fish b/fish/config.fish
new file mode 100644
index 0000000..9c4c5ed
--- /dev/null
+++ b/fish/config.fish
@@ -0,0 +1,23 @@
+if status is-interactive
+  # Commands to run in interactive sessions can go here
+  starship init fish | source
+  zoxide init fish | source
+
+  # Aliases
+  alias ls="exa"
+  alias lt="exa -T"
+  alias lT="exa -Tlh --no-user --no-time"
+  alias ll="exa -lh --no-user"
+  alias la="exa -lha --git --no-user"
+
+  # Global Variables
+
+  # Languages
+  ## Go
+  set -x GOROOT "$(brew --prefix golang)/libexec"
+  set -x GOPATH $HOME/go
+  set -x PATH $PATH $GOROOT/bin $GOPATH/bin
+
+  ## Flutter
+  set -x PATH $PATH "/opt/homebrew/Caskroom/flutter/2.10.4/flutter/bin"
+end
diff --git a/fish/fish_plugins b/fish/fish_plugins
new file mode 100644
index 0000000..9673b42
--- /dev/null
+++ b/fish/fish_plugins
@@ -0,0 +1,2 @@
+jorgebucaran/fisher
+jorgebucaran/nvm.fish
diff --git a/fish/fish_variables b/fish/fish_variables
new file mode 100644
index 0000000..490c8dc
--- /dev/null
+++ b/fish/fish_variables
@@ -0,0 +1,37 @@
+# This file contains fish universal variable definitions.
+# VERSION: 3.0
+SETUVAR __fish_initialized:3400
+SETUVAR _fisher_jorgebucaran_2F_fisher_files:/Users/boltless/\x2econfig/fish/functions/fisher\x2efish\x1e/Users/boltless/\x2econfig/fish/completions/fisher\x2efish
+SETUVAR _fisher_jorgebucaran_2F_nvm_2E_fish_files:/Users/boltless/\x2econfig/fish/functions/_nvm_index_update\x2efish\x1e/Users/boltless/\x2econfig/fish/functions/_nvm_list\x2efish\x1e/Users/boltless/\x2econfig/fish/functions/_nvm_version_activate\x2efish\x1e/Users/boltless/\x2econfig/fish/functions/_nvm_version_deactivate\x2efish\x1e/Users/boltless/\x2econfig/fish/functions/nvm\x2efish\x1e/Users/boltless/\x2econfig/fish/conf\x2ed/nvm\x2efish\x1e/Users/boltless/\x2econfig/fish/completions/nvm\x2efish
+SETUVAR _fisher_plugins:jorgebucaran/fisher\x1ejorgebucaran/nvm\x2efish
+SETUVAR fish_color_autosuggestion:555\x1ebrblack
+SETUVAR fish_color_cancel:\x2dr
+SETUVAR fish_color_command:blue
+SETUVAR fish_color_comment:red
+SETUVAR fish_color_cwd:green
+SETUVAR fish_color_cwd_root:red
+SETUVAR fish_color_end:green
+SETUVAR fish_color_error:brred
+SETUVAR fish_color_escape:brcyan
+SETUVAR fish_color_history_current:\x2d\x2dbold
+SETUVAR fish_color_host:normal
+SETUVAR fish_color_host_remote:yellow
+SETUVAR fish_color_normal:normal
+SETUVAR fish_color_operator:brcyan
+SETUVAR fish_color_param:cyan
+SETUVAR fish_color_quote:yellow
+SETUVAR fish_color_redirection:cyan\x1e\x2d\x2dbold
+SETUVAR fish_color_search_match:\x2d\x2dbackground\x3d111
+SETUVAR fish_color_selection:white\x1e\x2d\x2dbold\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_status:red
+SETUVAR fish_color_user:brgreen
+SETUVAR fish_color_valid_path:\x2d\x2dunderline
+SETUVAR fish_key_bindings:fish_default_key_bindings
+SETUVAR fish_pager_color_completion:normal
+SETUVAR fish_pager_color_description:B3A06D\x1eyellow\x1e\x2di
+SETUVAR fish_pager_color_prefix:cyan\x1e\x2d\x2dbold\x1e\x2d\x2dunderline
+SETUVAR fish_pager_color_progress:brwhite\x1e\x2d\x2dbackground\x3dcyan
+SETUVAR fish_pager_color_selected_background:\x2dr
+SETUVAR fish_user_paths:/opt/homebrew/bin
+SETUVAR nvm_data:/Users/boltless/\x2elocal/share/nvm
+SETUVAR nvm_mirror:https\x3a//nodejs\x2eorg/dist
diff --git a/fish/functions/_nvm_index_update.fish b/fish/functions/_nvm_index_update.fish
new file mode 100644
index 0000000..0ba3305
--- /dev/null
+++ b/fish/functions/_nvm_index_update.fish
@@ -0,0 +1,16 @@
+function _nvm_index_update --argument-names mirror index
+    if not command curl --location --silent $mirror/index.tab >$index.temp
+        command rm -f $index.temp
+        echo "nvm: Can't update index, host unavailable: \"$mirror\"" >&2
+        return 1
+    end
+
+    command awk -v OFS=\t '
+        /v0.9.12/ { exit } # Unsupported
+        NR > 1 {
+            print $1 (NR == 2  ? " latest" : $10 != "-" ? " lts/" tolower($10) : "")
+        }
+    ' $index.temp >$index
+
+    command rm -f $index.temp
+end
diff --git a/fish/functions/_nvm_list.fish b/fish/functions/_nvm_list.fish
new file mode 100644
index 0000000..fb5ab0e
--- /dev/null
+++ b/fish/functions/_nvm_list.fish
@@ -0,0 +1,11 @@
+function _nvm_list
+    set --local versions $nvm_data/*
+    set --query versions[1] &&
+        string match --entire --regex -- (string match --regex -- "v\d.+" $versions |
+            string escape --style=regex |
+            string join "|"
+        ) <$nvm_data/.index
+
+    command --all node |
+        string match --quiet --invert --regex -- "^$nvm_data" && echo system
+end
diff --git a/fish/functions/_nvm_version_activate.fish b/fish/functions/_nvm_version_activate.fish
new file mode 100644
index 0000000..b2aee92
--- /dev/null
+++ b/fish/functions/_nvm_version_activate.fish
@@ -0,0 +1,4 @@
+function _nvm_version_activate --argument-names v
+    set --global --export nvm_current_version $v
+    set --prepend PATH $nvm_data/$v/bin
+end
diff --git a/fish/functions/_nvm_version_deactivate.fish b/fish/functions/_nvm_version_deactivate.fish
new file mode 100644
index 0000000..540f697
--- /dev/null
+++ b/fish/functions/_nvm_version_deactivate.fish
@@ -0,0 +1,5 @@
+function _nvm_version_deactivate --argument-names v
+    test "$nvm_current_version" = "$v" && set --erase nvm_current_version
+    set --local index (contains --index -- $nvm_data/$v/bin $PATH) &&
+        set --erase PATH[$index]
+end
diff --git a/fish/functions/fisher.fish b/fish/functions/fisher.fish
new file mode 100644
index 0000000..6407479
--- /dev/null
+++ b/fish/functions/fisher.fish
@@ -0,0 +1,212 @@
+function fisher --argument-names cmd --description "A plugin manager for Fish"
+    set --query fisher_path || set --local fisher_path $__fish_config_dir
+    set --local fisher_version 4.3.1
+    set --local fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "Usage: fisher install <plugins...>  Install plugins"
+            echo "       fisher remove  <plugins...>  Remove installed plugins"
+            echo "       fisher update  <plugins...>  Update installed plugins"
+            echo "       fisher update                Update all installed plugins"
+            echo "       fisher list    [<regex>]     List installed plugins matching regex"
+            echo "Options:"
+            echo "       -v or --version  Print version"
+            echo "       -h or --help     Print this help message"
+            echo "Variables:"
+            echo "       \$fisher_path  Plugin installation path. Default: ~/.config/fish"
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove
+            isatty || read --local --null --array stdin && set --append argv $stdin
+
+            set --local install_plugins
+            set --local update_plugins
+            set --local remove_plugins
+            set --local arg_plugins $argv[2..-1]
+            set --local old_plugins $_fisher_plugins
+            set --local new_plugins
+
+            if ! set --query argv[2]
+                if test "$cmd" != update
+                    echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
+                else if test ! -e $fish_plugins
+                    echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins)
+            end
+
+            for plugin in $arg_plugins
+                test -e "$plugin" && set plugin (realpath $plugin)
+                contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
+            end
+
+            if set --query argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        test "$cmd" = remove &&
+                            set --append remove_plugins $plugin ||
+                            set --append update_plugins $plugin
+                    else if test "$cmd" = install
+                        set --append install_plugins $plugin
+                    else
+                        echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    contains -- "$plugin" $old_plugins &&
+                        set --append update_plugins $plugin ||
+                        set --append install_plugins $plugin
+                end
+
+                for plugin in $old_plugins
+                    contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
+                end
+            end
+
+            set --local pid_list
+            set --local source_plugins
+            set --local fetch_plugins $update_plugins $install_plugins
+            echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
+
+            for plugin in $fetch_plugins
+                set --local source (command mktemp -d)
+                set --append source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,functions}
+
+                fish --command "
+                    if test -e $plugin
+                        command cp -Rf $plugin/* $source
+                    else
+                        set temp (command mktemp -d)
+                        set name (string split \@ $plugin) || set name[2] HEAD
+                        set url https://api.github.com/repos/\$name[1]/tarball/\$name[2]
+                        set header 'Accept: application/vnd.github.v3+json'
+
+                        echo Fetching (set_color --underline)\$url(set_color normal)
+
+                        if curl --silent -L -H \$header \$url | tar -xzC \$temp -f - 2>/dev/null
+                            command cp -Rf \$temp/*/* $source
+                        else
+                            echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                            command rm -rf $source
+                        end
+                        command rm -rf \$temp
+                    end
+
+                    set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
+                " &
+
+                set --append pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set --local index (contains --index -- "$plugin" $install_plugins)
+                        set --erase install_plugins[$index]
+                    else
+                        set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set --local index (contains --index -- "$plugin" $_fisher_plugins)
+                    set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins
+                        for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                            emit {$name}_uninstall
+                        end
+                        printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) "         "$$plugin_files_var
+                    end
+
+                    command rm -rf $$plugin_files_var
+                    functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+
+                    for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                        complete --erase --command $name
+                    end
+
+                    set --erase _fisher_plugins[$index]
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set --query update_plugins[1] || set --query install_plugins[1]
+                command mkdir -p $fisher_path/{functions,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set --local files $source/{functions,conf.d,completions}/*
+
+                if set --local index (contains --index -- $plugin $install_plugins)
+                    set --local user_files $fisher_path/{functions,conf.d,completions}/*
+                    set --local conflict_files
+
+                    for file in (string replace -- $source/ $fisher_path/ $files)
+                        contains -- $file $user_files && set --append conflict_files $file
+                    end
+
+                    if set --query conflict_files[1] && set --erase install_plugins[$index]
+                        echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n"        "$conflict_files >&2
+                        continue
+                    end
+                end
+
+                for file in (string replace -- $source/ "" $files)
+                    command cp -Rf $source/$file $fisher_path/$file
+                end
+
+                set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+                set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files)
+
+                contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set --local event install || set --local event update
+
+                printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) "           "$$plugin_files_var
+
+                for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var)
+                    source $file
+                    if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
+                        emit {$name}_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+
+            set --query _fisher_plugins[1] || set --erase _fisher_plugins
+            set --query _fisher_plugins &&
+                printf "%s\n" $_fisher_plugins >$fish_plugins ||
+                command rm -f $fish_plugins
+
+            set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "Installed $total[1]") (
+                test $total[2] = 0 || echo "Updated $total[2]") (
+                test $total[3] = 0 || echo "Removed $total[3]")
+            ) plugin/s
+        case \*
+            echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
+    end
+end
+
+## Migrations ##
+function _fisher_fish_postexec --on-event fish_postexec
+    if functions --query _fisher_list
+        fisher update >/dev/null 2>/dev/null
+        set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
+        test -e $XDG_DATA_HOME/fisher && command rm -rf $XDG_DATA_HOME/fisher
+        functions --erase _fisher_list _fisher_plugin_parse
+        set --erase fisher_data
+    end
+    functions --erase _fisher_fish_postexec
+end
diff --git a/fish/functions/nvm.fish b/fish/functions/nvm.fish
new file mode 100644
index 0000000..77ec62e
--- /dev/null
+++ b/fish/functions/nvm.fish
@@ -0,0 +1,208 @@
+function nvm --argument-names cmd v --description "Node version manager"
+    if test -z "$v" && contains -- "$cmd" install use
+        for file in .nvmrc .node-version
+            set file (_nvm_find_up $PWD $file) && read v <$file && break
+        end
+        if test -z "$v"
+            echo "nvm: Invalid version or missing \".nvmrc\" file" >&2
+            return 1
+        end
+    end
+
+    set --local their_version $v
+
+    switch "$cmd"
+        case -v --version
+            echo "nvm, version 2.2.7"
+        case "" -h --help
+            echo "Usage: nvm install <version>    Download and activate the specified Node version"
+            echo "       nvm install              Install version from nearest .nvmrc file"
+            echo "       nvm use <version>        Activate a version in the current shell"
+            echo "       nvm use                  Activate version from nearest .nvmrc file"
+            echo "       nvm list                 List installed versions"
+            echo "       nvm list-remote          List versions available to install"
+            echo "       nvm list-remote <regex>  List versions matching a given regular expression"
+            echo "       nvm current              Print the currently-active version"
+            echo "       nvm uninstall <version>  Uninstall a version"
+            echo "Options:"
+            echo "       -v or --version          Print version"
+            echo "       -h or --help             Print this help message"
+            echo "Variables:"
+            echo "       nvm_arch                 Override architecture, e.g. x64-musl"
+            echo "       nvm_mirror               Set the Node download mirror"
+            echo "       nvm_default_version      Set the default version for new shells"
+        case install
+            _nvm_index_update $nvm_mirror $nvm_data/.index || return
+
+            string match --entire --regex -- (_nvm_version_match $v) <$nvm_data/.index | read v alias
+
+            if ! set --query v[1]
+                echo "nvm: Invalid version number or alias: \"$their_version\"" >&2
+                return 1
+            end
+
+            if test ! -e $nvm_data/$v
+                set --local os (command uname -s | string lower)
+                set --local ext tar.gz
+                set --local arch (command uname -m)
+
+                switch $os
+                    case aix
+                        set arch ppc64
+                    case sunos
+                    case linux
+                    case darwin
+                    case {MSYS_NT,MINGW\*_NT}\*
+                        set os win
+                        set ext zip
+                    case \*
+                        echo "nvm: Unsupported operating system: \"$os\"" >&2
+                        return 1
+                end
+
+                switch $arch
+                    case i\*86
+                        set arch x86
+                    case x86_64
+                        set arch x64
+                    case arm64
+                        string match --regex --quiet "v(?<major>\d+)" $v
+                        if test "$os" = darwin -a $major -lt 16
+                            set arch x64
+                        end
+                    case armv6 armv6l
+                        set arch armv6l
+                    case armv7 armv7l
+                        set arch armv7l
+                    case armv8 armv8l aarch64
+                        set arch arm64
+                end
+
+                set --query nvm_arch && set arch $nvm_arch
+
+                set --local dir "node-$v-$os-$arch"
+                set --local url $nvm_mirror/$v/$dir.$ext
+
+                command mkdir -p $nvm_data/$v
+
+                echo -e "Installing Node \x1b[1m$v\x1b[22m $alias"
+                echo -e "Fetching \x1b[4m$url\x1b[24m\x1b[7m"
+
+                if ! command curl --progress-bar --location $url \
+                        | command tar --extract --gzip --directory $nvm_data/$v 2>/dev/null
+                    command rm -rf $nvm_data/$v
+                    echo -e "\033[F\33[2K\x1b[0mnvm: Invalid mirror or host unavailable: \"$url\"" >&2
+                    return 1
+                end
+
+                echo -en "\033[F\33[2K\x1b[0m"
+
+                if test "$os" = win
+                    command mv $nvm_data/$v/$dir $nvm_data/$v/bin
+                else
+                    command mv $nvm_data/$v/$dir/* $nvm_data/$v
+                    command rm -rf $nvm_data/$v/$dir
+                end
+            end
+
+            if test $v != "$nvm_current_version"
+                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
+                _nvm_version_activate $v
+            end
+
+            printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
+        case use
+            test $v = default && set v $nvm_default_version
+            _nvm_list | string match --entire --regex -- (_nvm_version_match $v) | read v __
+
+            if ! set --query v[1]
+                echo "nvm: Can't use Node \"$their_version\", version must be installed first" >&2
+                return 1
+            end
+
+            if test $v != "$nvm_current_version"
+                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
+                test $v != system && _nvm_version_activate $v
+            end
+
+            printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
+        case uninstall
+            if test -z "$v"
+                echo "nvm: Not enough arguments for command: \"$cmd\"" >&2
+                return 1
+            end
+
+            test $v = default && test ! -z "$nvm_default_version" && set v $nvm_default_version
+
+            _nvm_list | string match --entire --regex -- (_nvm_version_match $v) | read v __
+
+            if ! set -q v[1]
+                echo "nvm: Node version not installed or invalid: \"$their_version\"" >&2
+                return 1
+            end
+
+            printf "Uninstalling Node %s %s\n" $v (string replace ~ \~ "$nvm_data/$v/bin/node")
+
+            _nvm_version_deactivate $v
+
+            command rm -rf $nvm_data/$v
+        case current
+            _nvm_current
+        case ls list
+            _nvm_list | _nvm_list_format (_nvm_current) $argv[2]
+        case lsr {ls,list}-remote
+            _nvm_index_update $nvm_mirror $nvm_data/.index || return
+            _nvm_list | command awk '
+                FILENAME == "-" && (is_local[$1] = FNR == NR) { next } {
+                    print $0 (is_local[$1] ? " ✓" : "")
+                }
+            ' - $nvm_data/.index | _nvm_list_format (_nvm_current) $argv[2]
+        case \*
+            echo "nvm: Unknown command or option: \"$cmd\" (see nvm -h)" >&2
+            return 1
+    end
+end
+
+function _nvm_find_up --argument-names path file
+    test -e "$path/$file" && echo $path/$file || begin
+        test "$path" != / || return
+        _nvm_find_up (command dirname $path) $file
+    end
+end
+
+function _nvm_version_match --argument-names v
+    string replace --regex -- '^v?(\d+|\d+\.\d+)$' 'v$1.' $v |
+        string replace --filter --regex -- '^v?(\d+)' 'v$1' |
+        string escape --style=regex ||
+        string lower '\b'$v'(?:/\w+)?$'
+end
+
+function _nvm_list_format --argument-names current regex
+    command awk -v current="$current" -v regex="$regex" '
+        $0 ~ regex {
+            aliases[versions[i++] = $1] = $2 " " $3
+            pad = (n = length($1)) > pad ? n : pad
+        }
+        END {
+            if (!i) exit 1
+            while (i--)
+                printf((current == versions[i] ? " ▶ " : "   ") "%"pad"s %s\n",
+                    versions[i], aliases[versions[i]])
+        }
+    '
+end
+
+function _nvm_current
+    command --search --quiet node || return
+    set --query nvm_current_version && echo $nvm_current_version || echo system
+end
+
+function _nvm_node_info
+    set --local npm_path (string replace bin/npm-cli.js "" (realpath (command --search npm)))
+    test -f $npm_path/package.json || set --local npm_version_default (command npm --version)
+    command node --eval "
+        console.log(process.version)
+        console.log('$npm_version_default' ? '$npm_version_default': require('$npm_path/package.json').version)
+        console.log(process.execPath.replace(require('os').homedir(), '~'))
+    "
+end
diff --git a/lf/lfrc b/lf/lfrc
new file mode 100644
index 0000000..76891ab
--- /dev/null
+++ b/lf/lfrc
@@ -0,0 +1,103 @@
+# interpreter for shell commands
+set shell sh
+
+# set '-eu' options for shell commands
+# These options are used to have safer shell commands. Option '-e' is used to
+# exit on error and option '-u' is used to give error for unset variables.
+# Option '-f' disables pathname expansion which can be useful when $f, $fs, and
+# $fx variables contain names with '*' or '?' characters. However, this option
+# is used selectively within individual commands as it can be limiting at
+# times.
+set shellopts '-eu'
+
+# set internal field separator (IFS) to "\n" for shell commands
+# This is useful to automatically split file names in $fs and $fx properly
+# since default file separator used in these variables (i.e. 'filesep' option)
+# is newline. You need to consider the values of these options and create your
+# commands accordingly.
+set ifs "\n"
+
+# leave some space at the top and the bottom of the screen
+set scrolloff 10
+
+# == previewer ==
+set previewer ~/.config/lf/previewer.sh
+
+# use enter for shell commands
+map <enter> shell
+
+# execute current file (must be executable)
+map x $$f
+map X !$f
+
+# dedicated keys for file opener actions
+map o &mimeopen $f
+map O $mimeopen --ask $f
+
+# define a custom 'open' command
+# This command is called when current file is not a directory. You may want to
+# use either file extensions and/or mime types here. Below uses an editor for
+# text files and a file opener for the rest.
+cmd open ${{
+    test -L $f && f=$(readlink -f $f)
+    case $(file --mime-type $f -b) in
+        text/*) $EDITOR $fx;;
+        *) for f in $fx; do setsid $OPENER $f > /dev/null 2> /dev/null & done;;
+    esac
+}}
+
+# define a custom 'rename' command without prompt for overwrite
+# cmd rename %[ -e $1 ] && printf "file exists" || mv $f $1
+# map r push :rename<space>
+
+# make sure trash folder exists
+# %mkdir -p ~/.trash
+
+# move current file or selected files to trash folder
+# (also see 'man mv' for backup/overwrite options)
+cmd trash %set -f; mv $fx ~/.trash
+
+# define a custom 'delete' command
+# cmd delete ${{
+#     set -f
+#     printf "$fx\n"
+#     printf "delete?[y/n]"
+#     read ans
+#     [ "$ans" = "y" ] && rm -rf $fx
+# }}
+
+# use '<delete>' key for either 'trash' or 'delete' command
+# map <delete> trash
+# map <delete> delete
+
+# extract the current file with the right command
+# (xkcd link: https://xkcd.com/1168/)
+cmd extract ${{
+    set -f
+    case $f in
+        *.tar.bz|*.tar.bz2|*.tbz|*.tbz2) tar xjvf $f;;
+        *.tar.gz|*.tgz) tar xzvf $f;;
+        *.tar.xz|*.txz) tar xJvf $f;;
+        *.zip) unzip $f;;
+        *.rar) unrar x $f;;
+        *.7z) 7z x $f;;
+    esac
+}}
+
+# compress current file or selected files with tar and gunzip
+cmd tar ${{
+    set -f
+    mkdir $1
+    cp -r $fx $1
+    tar czf $1.tar.gz $1
+    rm -rf $1
+}}
+
+# compress current file or selected files with zip
+cmd zip ${{
+    set -f
+    mkdir $1
+    cp -r $fx $1
+    zip -r $1.zip $1
+    rm -rf $1
+}}
diff --git a/lf/previewer.sh b/lf/previewer.sh
new file mode 100755
index 0000000..3c79dfe
--- /dev/null
+++ b/lf/previewer.sh
@@ -0,0 +1,9 @@
+#!/bin/sh
+
+# check here : https://www.youtube.com/watch?v=50BMBT05Wk0
+
+case ${1##*.} in
+  7z|zip) 7z l -p -- "$1" && exit 1;;
+  jpeg|jpg|png|gif) chafa --clear --animate=off --symbols space -s "$2x$3" "$1" && exit 1;;
+  *) bat --style=plain --color=always "$1" || cat "$1" && exit 1;;
+esac