{ lib, inputs, ... }:
{
  nixpkgs.overlays = [
    inputs.niri.overlays.niri
    (final: prev: {
      inherit (prev.lixPackageSets.stable)
        nixpkgs-review
        nix-eval-jobs
        nix-fast-build
        colmena
        ;
      electron = final.electron-bin;
      libime-jyutping = final.callPackage ../../pkgs/libime-jyutping { };
      musescore = prev.musescore.overrideAttrs (oldAttrs: {
        cmakeFlags = oldAttrs.cmakeFlags ++ [
          "-DMUSE_PIPEWIRE_AUDIO_DRIVER=ON"
        ];
        buildInputs = oldAttrs.buildInputs ++ [
          final.pipewire
        ];
      });
      linux-asahi-fairydust = final.callPackage ../../pkgs/linux-asahi-fairydust {
        src = inputs.fairydust;
      };
    })
  ];

  nixpkgs.config.allowUnfreePredicate =
    pkg:
    builtins.elem (lib.getName pkg) [
      "firefox-bin"
      "firefox-bin-unwrapped"
      "libfprint-2-tod1-elan"
      "steam"
      "steam-original"
      "steam-run"
      "steam-unwrapped"
      "storcli"
      "nvidia-x11"
      "nvidia-settings"
      "nvidia-persistenced"
    ];
}