{ inputs, ... }:
{
  flake.modules.nixos.dev-tools = {
    home-manager.sharedModules = [
      inputs.self.modules.homeManager.dev-tools
    ];
  };
  flake.modules.darwin.dev-tools =
    { pkgs, ... }:
    {
      home-manager.sharedModules = [
        inputs.self.modules.homeManager.dev-tools
      ];
      system.defaults.dock.persistent-apps = [
        "${pkgs.bruno}/Applications/Bruno.app/"
      ];
    };

  flake.modules.homeManager.dev-tools =
    { config, pkgs, ... }:
    let
      combinedDotnet = pkgs.dotnetCorePackages.combinePackages [
        pkgs.dotnet-sdk_8
        pkgs.dotnet-sdk_9
        pkgs.dotnet-sdk_10
      ];
    in
    {
      programs.go.enable = true;

      home.file.".nuget/plugins".source = pkgs.symlinkJoin {
        name = "dotnet-plugins";
        paths = [
          "${pkgs.local.artifacts-credprovider}/plugins"
        ];
      };

      sops.secrets."mcp_tokens/jira" = { };
      home.sessionVariables = {
        JIRA_API_TOKEN = "$(cat ${config.sops.secrets."mcp_tokens/jira".path})";
      };

      home.packages =
        let
          az = pkgs.azure-cli.withExtensions (
            with pkgs.azure-cli.extensions;
            [
              azure-devops
            ]
          );
        in
        with pkgs;
        [
          _unstable.acli
          _unstable.bun
          argocd
          az
          bruno
          inputs.grafana-cli.packages.${pkgs.stdenv.hostPlatform.system}.default
          inputs.graylog-cli.packages.${pkgs.stdenv.hostPlatform.system}.default
          local.clone_org
          mitmproxy
          nixd
          omnisharp-roslyn
          typescript-language-server
        ]
        ++ [ combinedDotnet ];
    };
}